mod_venk.t

Go to the documentation of this file.

module mod_venk
  ! Venkatakrishnan limiter
  !
  ! 2019.10.11 coded up by nanami;
  !
  ! see Venkatakrishnan 1993 for this limiter;
 
 
  implicit none
  private
 
  public :: venklimiter
 
contains
 
  subroutine venklimiter(ixI^L,iL^L,idims,dxdim,w,wLC,wRC)
    use mod_global_parameters
 
    integer, intent(in)             :: ixi^l, il^l, idims
    double precision, intent(in)    :: dxdim
    double precision, intent(in)    :: w(ixi^s,1:nw)
    double precision, intent(inout) :: wrc(ixi^s,1:nw),wlc(ixi^s,1:nw) 
    !> local
    integer                         :: im^l, imm^l, imp^l
    integer                         :: ilm^l, ilp^l, ilpp^l
    double precision                :: wmax(ixi^s,1:nw),wmin(ixi^s,1:nw)
    double precision                :: westp(ixi^s,1:nw),westm(ixi^s,1:nw)
    double precision                :: phi1(ixi^s,1:nw),phi2(ixi^s,1:nw)
    double precision                :: phi3(ixi^s,1:nw),phi4(ixi^s,1:nw)
    double precision                :: phim(ixi^s,1:nw),phip(ixi^s,1:nw),phi(ixi^s,1:nw)
    double precision                :: deltap(ixi^s,1:nw),deltam(ixi^s,1:nw)
    double precision                :: eps2
    double precision, parameter     :: venk_omega = 1.d-12
    double precision, parameter     :: venk_k = 0.3d0
 
    im^l=il^l;
    immax^d=ilmax^d+kr(idims,^d);
    ilm^l=il^l-kr(idims,^d);
    imm^l=im^l-kr(idims,^d);
    ilp^l=il^l+kr(idims,^d);
    imp^l=im^l+kr(idims,^d);
    ilpp^l=ilp^l+kr(idims,^d);
 
    eps2 = (venk_k * dxdim) ** 3
 
    wmax(im^s,1:nwflux) = max(w(imm^s,1:nwflux), w(im^s,1:nwflux), w(imp^s,1:nwflux))
    wmin(im^s,1:nwflux) = min(w(imm^s,1:nwflux), w(im^s,1:nwflux), w(imp^s,1:nwflux))
    !> use central difference approximation as (eq.5) and take phi = 1
    westp(im^s,1:nwflux) = w(im^s,1:nwflux) + (w(imp^s,1:nwflux) - w(imm^s,1:nwflux)) * 0.25d0
    westm(im^s,1:nwflux) = w(im^s,1:nwflux) - (w(imp^s,1:nwflux) - w(imm^s,1:nwflux)) * 0.25d0
 
    !> (eq.30) & (eq.31)
    deltap = 0
    deltam = 0
    phi1 = 0
    phi2 = 0
    phip = 1
    where(westp(im^s,1:nwflux) .gt. w(im^s,1:nwflux))
      deltap(im^s,1:nwflux) = wmax(im^s,1:nwflux) - w(im^s,1:nwflux)
      deltam(im^s,1:nwflux) = westp(im^s,1:nwflux) - w(im^s,1:nwflux)
      deltam(im^s,1:nwflux) = sign(dabs(deltam(im^s,1:nwflux)) + venk_omega, deltam(im^s,1:nwflux))
      phi1(im^s,1:nwflux) = (deltap(im^s,1:nwflux)**2 + eps2) + 2.d0 * deltap(im^s,1:nwflux) * deltam(im^s,1:nwflux)
      phi2(im^s,1:nwflux) = deltap(im^s,1:nwflux)**2 + 2.d0 * deltam(im^s,1:nwflux)**2 + deltap(im^s,1:nwflux) * deltam(im^s,1:nwflux) + eps2
      phip(im^s,1:nwflux) = phi1(im^s,1:nwflux) / phi2(im^s, 1:nwflux)
    elsewhere(westp(im^s,1:nwflux) .lt. w(im^s,1:nwflux))
      deltap(im^s,1:nwflux) = wmin(im^s,1:nwflux) - w(im^s,1:nwflux)
      deltam(im^s,1:nwflux) = westp(im^s,1:nwflux) - w(im^s,1:nwflux)
      deltam(im^s,1:nwflux) = sign(dabs(deltam(im^s,1:nwflux)) + venk_omega, deltam(im^s,1:nwflux))
      phi1(im^s,1:nwflux) = (deltap(im^s,1:nwflux)**2 + eps2) + 2.d0 * deltap(im^s,1:nwflux) * deltam(im^s,1:nwflux)
      phi2(im^s,1:nwflux) = deltap(im^s,1:nwflux)**2 + 2.d0 * deltam(im^s,1:nwflux)**2 + deltap(im^s,1:nwflux) * deltam(im^s,1:nwflux) + eps2
      phip(im^s,1:nwflux) = phi1(im^s,1:nwflux) / phi2(im^s, 1:nwflux)
    elsewhere
      phip(im^s,1:nwflux) = one
   endwhere
 
    deltap = 0
    deltam = 0
    phi3 = 0
    phi4 = 0
    phim = 0
    where(westm(im^s,1:nwflux) .lt. w(im^s,1:nwflux))
      deltap(im^s,1:nwflux) = - (wmax(im^s,1:nwflux) - w(im^s,1:nwflux))
      deltam(im^s,1:nwflux) = westm(im^s,1:nwflux) - w(im^s,1:nwflux)
      deltam(im^s,1:nwflux) = sign(dabs(deltam(im^s,1:nwflux)) + venk_omega, deltam(im^s,1:nwflux))
      phi3(im^s,1:nwflux) = (deltap(im^s,1:nwflux)**2 + eps2) + 2.d0 * deltap(im^s,1:nwflux) * deltam(im^s,1:nwflux)
      phi4(im^s,1:nwflux) = deltap(im^s,1:nwflux)**2 + 2.d0 * deltam(im^s,1:nwflux)**2 + deltap(im^s,1:nwflux) * deltam(im^s,1:nwflux) + eps2
      phim(im^s,1:nwflux) = phi3(im^s,1:nwflux) / phi4(im^s, 1:nwflux)
    elsewhere(westm(im^s,1:nwflux) .gt. w(im^s,1:nwflux))
      deltap(im^s,1:nwflux) = - (wmin(im^s,1:nwflux) - w(im^s,1:nwflux))
      deltam(im^s,1:nwflux) = westm(im^s,1:nwflux) - w(im^s,1:nwflux)
      deltam(im^s,1:nwflux) = sign(dabs(deltam(im^s,1:nwflux)) + venk_omega, deltam(im^s,1:nwflux))
      phi3(im^s,1:nwflux) = (deltap(im^s,1:nwflux)**2 + eps2) + 2.d0 * deltap(im^s,1:nwflux) * deltam(im^s,1:nwflux)
      phi4(im^s,1:nwflux) = deltap(im^s,1:nwflux)**2 + 2.d0 * deltam(im^s,1:nwflux)**2 + deltap(im^s,1:nwflux) * deltam(im^s,1:nwflux) + eps2
      phim(im^s,1:nwflux) = phi3(im^s,1:nwflux) / phi4(im^s, 1:nwflux)
    elsewhere
      phim(im^s,1:nwflux) = one
    endwhere
    !> (eq.3)
    phi(im^s,1:nwflux) = min(phim(im^s,1:nwflux),phip(im^s,1:nwflux))
    !> (eq.5)
    wlc(il^s,1:nwflux) = w(il^s,1:nwflux) + 0.25d0 * (w(ilp^s,1:nwflux)-w(ilm^s,1:nwflux)) * phi(il^s,1:nwflux)
    wrc(il^s,1:nwflux) = w(ilp^s,1:nwflux) - 0.25d0 * (w(ilpp^s,1:nwflux)-w(il^s,1:nwflux)) * phi(ilp^s,1:nwflux)
 
  end subroutine venklimiter
 
end module mod_venk